home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / programm.ing / falcon / nt_dsp1.lzh / NT_DSP1.MSA / FFT / DHIT1.ASM < prev    next >
Encoding:
Assembly Source File  |  1990-01-17  |  1.8 KB  |  43 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Discrete Hilbert Transform in the frequency domain
  7. ; 
  8. ; Last Update 18 Aug 88   Version 1.0
  9. ;
  10. dhit macro points,data
  11. dhit ident 1,0
  12.      opt nomd,mex
  13. ;
  14. ;Compute Hilbert transform in the frequency domain. This routine
  15. ;starts with "points" frequency domain data, located at "data", with real part
  16. ;in X-memory and imaginary part in Y-memory. The program gives the first 
  17. ;half of the frequency data a phase shift of -90 degrees ("positive 
  18. ;frequency" part) and the second half of the data a phase shift of +90
  19. ;degrees ("negative frequency" part). The magnitude of the complex
  20. ;data remains unchanged. The output data points are located at the same
  21. ;location.
  22. ;
  23.      move #data,r0           ;point to the positive-frequency data (real part)
  24.      move #-1,m0              ;linear addressing for 
  25.      move m0,m1               ;all pointers
  26.      move m0,m4
  27.      move m0,m5
  28.      move #data+points/2,r1  ;point to the negative-frequency data (real part)
  29.      move r0,r4               ;point to the positive-frequency data (imaginary part)
  30.      move r1,r5               ;point to the negative-frequency data (imaginary part)
  31.  
  32.      do #points/2,endloop      ;do for all frequency points
  33.  
  34.      move x:(r0),a  y:(r4),b            ;real -> a, imaginary -> b
  35.      neg a                              ;real part becomes - imaginary part
  36.      move      b,x:(r0)+ a,y:(r4)+      ;store real and imaginary parts
  37.      move      x:(r1),a  y:(r5),b       ;get negative-frequency data
  38.      neg  b                             ;imaginary part becomes - real part    
  39.      move      b,x:(r5)+ a,y:(r1)+      ;store negative-frequency data
  40. endloop
  41.      endm
  42.  
  43. ^Z